<![CDATA[Latest posts for the topic "Làm ơn giúp em cách tạo folder + uploadfile bằng ASP 3.0!"]]> /hvaonline/posts/list/23.html JForum - http://www.jforum.net Làm ơn giúp em cách tạo folder + uploadfile bằng ASP 3.0! VD: em đang để toàn bộ web của em ở ổ D: chẳng hạn,cả CSDL cũng ở đó luôn ~> em muốn tạo 1 trang ASP có chắc năng tạo thêm folder trong ổ D: này.Sau khi tạo được folder rồi thì em muốn copy 1 flie bất kỳ từ ổ C: chẳng hạn vào folder vừa tạo ra đó. :-o) ~> mong các bác giúp dùm ạ! Tiện thể các bác có thể hướng dẫn em tạo 1 trang ASP3.0 để up nhiều file cùng 1 lúc nhé, và những file đó có thể đến từ nhiều nguồn khác nhau nhưng khi up xong thì nó đều nằm chung trong 1 thư mục do mình chỉ định. Em cảm ơn trước! ]]> /hvaonline/posts/list/11228.html#64607 /hvaonline/posts/list/11228.html#64607 GMT Làm ơn giúp em cách tạo folder + uploadfile bằng ASP 3.0! /hvaonline/posts/list/11228.html#65807 /hvaonline/posts/list/11228.html#65807 GMT Làm ơn giúp em cách tạo folder + uploadfile bằng ASP 3.0!

gulic wrote:
sao k0 có ai giúp em hết vậy? Các bác ơi chỉ giùm với 
Bạn hãy nghiên cứu phần FileSystemObject trong ASP nhé, nó có thể xoá, di chuyển, tạo mới file và folder trên server. bạn có thể tham khảo tại địa chỉ trên http://www.w3schools.com/asp/asp_ref_filesystem.asp Chúc bạn sớm thành công]]> /hvaonline/posts/list/11228.html#65816 /hvaonline/posts/list/11228.html#65816 GMT Làm ơn giúp em cách tạo folder + uploadfile bằng ASP 3.0! /hvaonline/posts/list/11228.html#65934 /hvaonline/posts/list/11228.html#65934 GMT Làm ơn giúp em cách tạo folder + uploadfile bằng ASP 3.0! Code:
<%
Dim tBytes
Dim binData
Dim Dict
Dim fileName
Dim fso
Dim fsoFile
Dim binaryFileContent
Dim i
tBytes = Request.TotalBytes
binData = Request.BinaryRead(tBytes)
Set Dict = BuildUploadRequest(binData)
fileName = Dict.Item("fName").Item("FileName")
binaryFileContent = Dict.Item("fName").Item("Value")
fileName = ParseFileFromPath(fileName)
fname=filename
fileName = Server.MapPath("/") & "\photos\" & fileName
'fileName = "C:\Article\" & fileName

'==constructing the filepath of the root on server 
Set fso = Server.CreateObject("Scripting.FileSystemObject")
Set fsoFile = fso.CreateTextFile(fileName, True)
For i = 1 To LenB(binaryFileContent)
	fsoFile.Write Chr(AscB(MidB(binaryFileContent, i, 1)))
Next 
fsoFile.Close
Set fso = Nothing

'-------------------------------------------------------------------
Function getString(StringBin)
	getString =""
	For intCount = 1 To LenB(StringBin)
		getString = getString & chr(AscB(MidB(StringBin,intCount,1))) 
	Next
End Function

'-------------------------------------------------------------------
Function getByteString(StringStr)
	For i = 1 To Len(StringStr)
		char = Mid(StringStr, i, 1)
		getByteString = getByteString & chrB(AscB(char))
	Next
End Function

'-------------------------------------------------------------------
Function BuildUploadRequest(RequestBin)
	Dim scrDict
	Set scrDict = Server.CreateObject("Scripting.Dictionary")
	PosBeg = 1
	PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
	boundary = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
	boundaryPos = InstrB(1,RequestBin,boundary)
	Do until (boundaryPos=InstrB(RequestBin,boundary & getByteString("--")))
		Dim UploadControl
		Set UploadControl = CreateObject("Scripting.Dictionary")
		Pos = InstrB(BoundaryPos,RequestBin, getByteString("Content-Disposition"))
		Pos = InstrB(Pos,RequestBin,getByteString("name="))
		PosBeg = Pos+6
		PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
		Name = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
		PosFile=InstrB(BoundaryPos,RequestBin,getByteString("filename="))
		PosBound = InstrB(PosEnd,RequestBin,boundary)
		If PosFile<>0 AND (PosFile<PosBound) Then
			PosBeg = PosFile + 10
			PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
			FileName = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
			UploadControl.Add "FileName", FileName
			Pos = InstrB(PosEnd,RequestBin,getByteString("Content-Type:"))
			PosBeg = Pos+14
			PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
			ContentType = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
			UploadControl.Add "ContentType",ContentType
			PosBeg = PosEnd+4
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
			Value = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
		Else
			Pos = InstrB(Pos,RequestBin,getByteString(chr(13)))
			PosBeg = Pos+4
			PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
			Value = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
		End If
		UploadControl.Add "Value" , Value
		scrDict.Add Name, UploadControl
	BoundaryPos=InstrB(BoundaryPos+LenB(boundary),RequestBin,boundary)
	Loop
	
	Set BuildUploadRequest = scrDict
	Set scrDict = Nothing
End Function

'-------------------------------------------------------------------
Function ParseFileFromPath(iStr)
	Dim tPos
	tPos = InStrRev(iStr, "\")
	If tPos = 0 Or IsNull(tPos) Then
		ParseFileFromPath = iStr
		Exit Function
	End If
	ParseFileFromPath = Right(iStr, Len(iStr) - tPos)
End Function

%>
<HTML>
<HEAD>
<title>Upload Picture</title>
<STYLE type="text/css"> 
<!--
.link1 {text-decoration: none;}
A:hover {color : Red;}
BODY {font-family:Arial; font-size:10pt;}
TABLE {font-family:Arial; font-size:10pt;}
 -->
</STYLE>
</HEAD>

<BODY>
<br><br><center>
<b><a href="../photos/<%=fname%>">
<%=fname%></a></b> 
has been uploaded successfully...<br><br>
Thank you for using our service.
</center>
</BODY>
</HTML>
]]> /hvaonline/posts/list/11228.html#66555 /hvaonline/posts/list/11228.html#66555 GMT Làm ơn giúp em cách tạo folder + uploadfile bằng ASP 3.0! /hvaonline/posts/list/11228.html#67025 /hvaonline/posts/list/11228.html#67025 GMT