{
  Solution for Vortex level 0 wargame (http://www.overthewire.org/wargames/vortex/level0)
  This console application will:
    - connect to Vortex server
    - calculate 4 numbers
    - sending result back to server
    and we got username & password

  Written by LeVuHoang
}

program Vortext0;

{$APPTYPE CONSOLE}

uses
  ScktComp,
  SysUtils,
  Windows;

const
  cHost = 'vortex.labs.pulltheplug.org'; // your host name here
  cPort = 5842;                          // remote host port

type
  TSocketMethodDispatcher = class(TObject)
  public
    procedure OnClientRead(Sender: TObject; Socket: TCustomWinSocket);
    procedure OnClientError(Sender: TObject; Socket: TCustomWinSocket; ErrorEvent: TErrorEvent; var ErrorCode: Integer);
    procedure OnConnect(Sender: TObject; Socket: TCustomWinSocket);
  end; // TSocketMethodDispatcher

var
  vSocketMethodDispatcher: TSocketMethodDispatcher;
  vClientSocket: TClientSocket;

  iTotal: Longint = 0; // Total of four numbers
  iCount: Byte = 0;    // counter

  Msg: TMsg;           // window messages

//
// get error messages from server
//
procedure TSocketMethodDispatcher.OnClientError(Sender: TObject; Socket: TCustomWinSocket; ErrorEvent: TErrorEvent; var ErrorCode: Integer);
begin
  Writeln('Error: ', Socket.ReceiveText);
  ErrorCode :=0;
end;

//
// display connected message
//
procedure TSocketMethodDispatcher.OnConnect(Sender: TObject; Socket: TCustomWinSocket);
begin
  Writeln('Connected to: ', Socket.RemoteHost);
end;

//
// get data from server
//
procedure TSocketMethodDispatcher.OnClientRead(Sender: TObject; Socket: TCustomWinSocket);
var
  iNumber: Integer;
begin
  inc(iCount);

  //
  // receive 4 integer numbers
  //
  if iCount <= 4 then
  begin
    Socket.ReceiveBuf(iNumber, SizeOf(iNumber));
    iTotal :=iTotal + iNumber;

    //
    // diplay each number
    //
    Writeln(Format('Number%d = %d, Total = %d', [iCount, iNumber, iTotal]));
  end; // if

  //
  // we have the total now
  // send back to server
  //
  if iCount = 4 then
  begin
    Writeln('Sending result: ', iTotal);
    Socket.SendBuf(iTotal, SizeOf(iTotal));
  end; // 4

  //
  // finally, we got username & password
  //
  if iCount = 5 then
  begin
    Writeln;
    Writeln('Yahhhhhhhhhhooooooooooooo!!!!!!!! Here is your account.');
    Writeln(Socket.ReceiveText);
  end; // if
end; // TSocketMethodDispatcher.

begin
  vSocketMethodDispatcher :=TSocketMethodDispatcher.Create;
  vClientSocket :=TClientSocket.Create(nil);
  vClientSocket.Host :=cHost;
  vClientSocket.Port :=cPort;

  //
  // socket events
  //
  vClientSocket.OnRead :=vSocketMethodDispatcher.OnClientRead;
  vClientSocket.OnConnect :=vSocketMethodDispatcher.OnConnect;
  vClientSocket.OnError :=vSocketMethodDispatcher.OnClientError;

  //
  // connecting to server
  //
  Writeln('Connecting to: ', cHost);
  vClientSocket.Active :=True;

  // wait until the console is closed
  while GetMessage(Msg,0,0,0) do
  begin
    TranslateMessage(Msg);
    DispatchMessage(Msg);
  end; // while

  // free resources
  vClientSocket.Free;
  vSocketMethodDispatcher.Free;
end.

unsigned char buf[512];
unsigned char *ptr = buf + (sizeof(buf)/2);
.....

case '\\': ptr--; break;
default: e(); if(ptr > buf + sizeof(buf)) continue; ptr++[0] = x;